Add ability to strip binaries in cmake

CMakeLists.txt

@@ -263,6 +263,11 @@ if (OBJCOPY_PATH AND YANDEX_OFFICIAL_BUILD AND (NOT CMAKE_TOOLCHAIN_FILE))
     set (USE_BINARY_HASH 1)
 endif ()
 
+# Allows to build stripped binary in a separate directory
+if (OBJCOPY_PATH AND READELF_PATH)
+    set(BUILD_STRIPPED_BINARIES_PREFIX "" CACHE STRING "Build stripped binaries with debug info in separate directory")
+endif()
+
 cmake_host_system_information(RESULT AVAILABLE_PHYSICAL_MEMORY QUERY AVAILABLE_PHYSICAL_MEMORY) # Not available under freebsd
 
 

cmake/strip.sh

@@ -0,0 +1,25 @@
+#!/usr/bin/env bash
+
+BINARY_PATH=$1
+BINARY_NAME=$(basename $BINARY_PATH)
+DESTINATION_STRIPPED_DIR=$2
+OBJCOPY_PATH=${3:objcopy}
+READELF_PATH=${4:readelf}
+
+BUILD_ID=$($READELF_PATH -n $1 | sed -n '/Build ID/ { s/.*: //p; q; }')
+BUILD_ID_PREFIX=${BUILD_ID:0:2}
+BUILD_ID_SUFFIX=${BUILD_ID:2}
+TEMP_BINARY_PATH="${BINARY_PATH}_temp"
+
+DESTINATION_DEBUG_INFO_DIR="$DESTINATION_STRIPPED_DIR/lib/debug/.build-id"
+DESTINATION_STRIP_BINARY_DIR="$DESTINATION_STRIPPED_DIR/bin"
+
+mkdir -p "$DESTINATION_DEBUG_INFO_DIR/$BUILD_ID_PREFIX"
+mkdir -p "$DESTINATION_STRIP_BINARY_DIR"
+
+$OBJCOPY_PATH --only-keep-debug "$BINARY_PATH" "$DESTINATION_DEBUG_INFO_DIR/$BUILD_ID_PREFIX/$BUILD_ID_SUFFIX.debug"
+
+touch "$TEMP_BINARY_PATH"
+$OBJCOPY_PATH --add-gnu-debuglink "$DESTINATION_DEBUG_INFO_DIR/$BUILD_ID_PREFIX/$BUILD_ID_SUFFIX.debug" "$BINARY_PATH" "$TEMP_BINARY_PATH"
+$OBJCOPY_PATH --strip-all "$TEMP_BINARY_PATH" "$DESTINATION_STRIP_BINARY_DIR/$BINARY_NAME"
+rm -f "$TEMP_BINARY_PATH"

cmake/strip_binary.cmake

@@ -0,0 +1,30 @@
+# add_custom_command(TARGET clickhouse POST_BUILD COMMAND
+# ./clickhouse hash-binary > hash && ${OBJCOPY_PATH} --add-section .note.ClickHouse.hash=hash
+# clickhouse COMMENT "Adding .note.ClickHouse.hash to clickhouse" VERBATIM)
+
+macro(clickhouse_strip_binary)
+   set(oneValueArgs TARGET DESTINATION_DIR BINARY_PATH)
+
+   cmake_parse_arguments(STRIP "" "${oneValueArgs}" "" ${ARGN})
+
+   if (NOT DEFINED STRIP_TARGET)
+       message(FATAL_ERROR "A target name must be provided for stripping binary")
+   endif()
+
+   if (NOT DEFINED STRIP_BINARY_PATH)
+       message(FATAL_ERROR "A binary path name must be provided for stripping binary")
+   endif()
+
+
+   if (NOT DEFINED STRIP_DESTINATION_DIR)
+       message(FATAL_ERROR "Destination directory for stripped binary must be provided")
+   endif()
+
+   add_custom_command(TARGET ${STRIP_TARGET} POST_BUILD
+     COMMAND bash ${ClickHouse_SOURCE_DIR}/cmake/strip.sh ${STRIP_BINARY_PATH} ${STRIP_DESTINATION_DIR} ${OBJCOPY_PATH} ${READELF_PATH}
+     COMMENT "Stripping clickhouse binary" VERBATIM
+   )
+
+   install(PROGRAMS ${STRIP_DESTINATION_DIR}/bin/${STRIP_TARGET} DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+   install(DIRECTORY ${STRIP_DESTINATION_DIR}/lib/debug DESTINATION ${CMAKE_INSTALL_LIBDIR} COMPONENT clickhouse)
+endmacro()

cmake/tools.cmake

@@ -169,3 +169,31 @@ if (OBJCOPY_PATH)
 else ()
     message (FATAL_ERROR "Cannot find objcopy.")
 endif ()
+
+if (COMPILER_GCC)
+    find_program (READELF_PATH NAMES "llvm-readelf" "llvm-readelf-13" "llvm-readelf-12" "llvm-readelf-11" "readelf")
+else ()
+    find_program (READELF_PATH NAMES "llvm-readelf-${COMPILER_VERSION_MAJOR}" "llvm-readelf" "readelf")
+endif ()
+
+if (NOT READELF_PATH AND OS_DARWIN)
+    find_program (BREW_PATH NAMES "brew")
+    if (BREW_PATH)
+        execute_process (COMMAND ${BREW_PATH} --prefix llvm ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE OUTPUT_VARIABLE LLVM_PREFIX)
+        if (LLVM_PREFIX)
+            find_program (READELF_PATH NAMES "llvm-readelf" PATHS "${LLVM_PREFIX}/bin" NO_DEFAULT_PATH)
+        endif ()
+        if (NOT READELF_PATH)
+            execute_process (COMMAND ${BREW_PATH} --prefix binutils ERROR_QUIET OUTPUT_STRIP_TRAILING_WHITESPACE OUTPUT_VARIABLE BINUTILS_PREFIX)
+            if (BINUTILS_PREFIX)
+                find_program (READELF_PATH NAMES "readelf" PATHS "${BINUTILS_PREFIX}/bin" NO_DEFAULT_PATH)
+            endif ()
+        endif ()
+    endif ()
+endif ()
+
+if (READELF_PATH)
+    message (STATUS "Using readelf: ${READELF_PATH}")
+else ()
+    message (FATAL_ERROR "Cannot find readelf.")
+endif ()

programs/CMakeLists.txt

@@ -2,6 +2,8 @@ if (USE_CLANG_TIDY)
     set (CMAKE_CXX_CLANG_TIDY "${CLANG_TIDY_PATH}")
 endif ()
 
+include(${ClickHouse_SOURCE_DIR}/cmake/strip_binary.cmake)
+
 # The `clickhouse` binary is a multi purpose tool that contains multiple execution modes (client, server, etc.),
 # each of them may be built and linked as a separate library.
 # If you do not know what modes you need, turn this option OFF and enable SERVER and CLIENT only.
@@ -455,7 +457,9 @@ else ()
         list(APPEND CLICKHOUSE_BUNDLE clickhouse-keeper-converter)
     endif ()
 
-    install (TARGETS clickhouse RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+    if (NOT BUILD_STRIPPED_BINARIES_PREFIX)
+        install (TARGETS clickhouse RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+    endif()
 
     add_custom_target (clickhouse-bundle ALL DEPENDS ${CLICKHOUSE_BUNDLE})
 
@@ -466,7 +470,13 @@ else ()
     if (USE_BINARY_HASH)
         add_custom_command(TARGET clickhouse POST_BUILD COMMAND ./clickhouse hash-binary > hash && ${OBJCOPY_PATH} --add-section .note.ClickHouse.hash=hash clickhouse COMMENT "Adding .note.ClickHouse.hash to clickhouse" VERBATIM)
     endif()
-endif ()
+
+    if (BUILD_STRIPPED_BINARIES_PREFIX)
+        clickhouse_strip_binary(TARGET clickhouse DESTINATION_DIR ${CMAKE_CURRENT_BINARY_DIR}/${BUILD_STRIPPED_BINARIES_PREFIX} BINARY_PATH clickhouse)
+    endif()
+endif()
+
+
 
 if (ENABLE_TESTS)
     set (CLICKHOUSE_UNIT_TESTS_TARGETS unit_tests_dbms)

programs/library-bridge/CMakeLists.txt

@@ -1,3 +1,5 @@
+include(${ClickHouse_SOURCE_DIR}/cmake/strip_binary.cmake)
+
 set (CLICKHOUSE_LIBRARY_BRIDGE_SOURCES
     library-bridge.cpp
     LibraryInterface.cpp
@@ -22,4 +24,10 @@ target_link_libraries(clickhouse-library-bridge PRIVATE
 
 set_target_properties(clickhouse-library-bridge PROPERTIES RUNTIME_OUTPUT_DIRECTORY ..)
 
-install(TARGETS clickhouse-library-bridge RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+if (BUILD_STRIPPED_BINARIES_PREFIX)
+    clickhouse_strip_binary(TARGET clickhouse-library-bridge DESTINATION_DIR ${CMAKE_CURRENT_BINARY_DIR}/../${BUILD_STRIPPED_BINARIES_PREFIX} BINARY_PATH ../clickhouse-library-bridge)
+endif()
+
+if (NOT BUILD_STRIPPED_BINARIES_PREFIX)
+    install(TARGETS clickhouse-library-bridge RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+endif()

programs/odbc-bridge/CMakeLists.txt

@@ -1,3 +1,5 @@
+include(${ClickHouse_SOURCE_DIR}/cmake/strip_binary.cmake)
+
 set (CLICKHOUSE_ODBC_BRIDGE_SOURCES
     ColumnInfoHandler.cpp
     getIdentifierQuote.cpp
@@ -37,7 +39,13 @@ if (USE_GDB_ADD_INDEX)
     add_custom_command(TARGET clickhouse-odbc-bridge POST_BUILD COMMAND ${GDB_ADD_INDEX_EXE} ../clickhouse-odbc-bridge COMMENT "Adding .gdb-index to clickhouse-odbc-bridge" VERBATIM)
 endif()
 
-install(TARGETS clickhouse-odbc-bridge RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+if (BUILD_STRIPPED_BINARIES_PREFIX)
+    clickhouse_strip_binary(TARGET clickhouse-odbc-bridge DESTINATION_DIR ${CMAKE_CURRENT_BINARY_DIR}/../${BUILD_STRIPPED_BINARIES_PREFIX} BINARY_PATH ../clickhouse-odbc-bridge)
+endif()
+
+if (NOT BUILD_STRIPPED_BINARIES_PREFIX)
+    install(TARGETS clickhouse-odbc-bridge RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR} COMPONENT clickhouse)
+endif()
 
 if(ENABLE_TESTS)
     add_subdirectory(tests)

programs/server/CMakeLists.txt

@@ -36,4 +36,6 @@ clickhouse_embed_binaries(
     TARGET clickhouse_server_configs
     RESOURCES config.xml users.xml embedded.xml play.html
 )
+
+
 add_dependencies(clickhouse-server-lib clickhouse_server_configs)