mirror of
https://github.com/ClickHouse/ClickHouse.git
synced 2024-09-19 16:20:50 +00:00
4c043301e6
This will fix with issues like this [1]:
Aug 12 09:58:44 '/usr/bin/cmake' '--build' '/build/build_docker/native' '--target' 'pre_compressor'
Aug 12 09:58:44 sccache: error: Server startup failed: cache storage failed to read: Unexpected (temporary) at stat
Aug 12 09:58:45 ninja: build stopped: subcommand failed.
Aug 12 09:58:45 -- Configuring done (77.7s)
Aug 12 09:58:47 -- Generating done (1.8s)
Aug 12 09:58:47 -- Build files have been written to: /build/build_docker
So as you can see even if ninja fails it still wrote build files, while
it should fail.
[1]: https://s3.amazonaws.com/clickhouse-test-reports/64955/0af41e32a5822d25ac3760f1ebb2313557474701/builds/report.html
[2]: 0af41e32a5/binary_darwin_aarch64/build_log.log
Note, COMMAND_ERROR_IS_FATAL is 3.19+, and the requirement for now is
3.20
Signed-off-by: Azat Khuzhin <a.khuzhin@semrush.com>
79 lines
3.0 KiB
CMake
79 lines
3.0 KiB
CMake
set(LIBRARY_DIR "${ClickHouse_SOURCE_DIR}/contrib/cctz")
|
|
|
|
set (SRCS
|
|
"${LIBRARY_DIR}/src/civil_time_detail.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_fixed.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_format.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_if.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_impl.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_info.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_libc.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_lookup.cc"
|
|
"${LIBRARY_DIR}/src/time_zone_posix.cc"
|
|
"${LIBRARY_DIR}/src/zone_info_source.cc"
|
|
)
|
|
|
|
add_library (_cctz ${SRCS})
|
|
target_include_directories (_cctz PUBLIC "${LIBRARY_DIR}/include")
|
|
|
|
if (OS_FREEBSD)
|
|
# yes, need linux, because bsd check inside linux in time_zone_libc.cc:24
|
|
target_compile_definitions (_cctz PRIVATE __USE_BSD linux _XOPEN_SOURCE=600)
|
|
endif ()
|
|
|
|
# Related to time_zones table:
|
|
# TimeZones.generated.cpp is autogenerated each time during a build
|
|
set(TIMEZONES_FILE "${CMAKE_CURRENT_BINARY_DIR}/TimeZones.generated.cpp")
|
|
# remove existing copies so that its generated fresh on each build.
|
|
file(REMOVE ${TIMEZONES_FILE})
|
|
|
|
# get the list of timezones from tzdata shipped with cctz
|
|
set(TZDIR "${LIBRARY_DIR}/testdata/zoneinfo")
|
|
file(STRINGS "${LIBRARY_DIR}/testdata/version" TZDATA_VERSION)
|
|
set_property(GLOBAL PROPERTY TZDATA_VERSION_PROP "${TZDATA_VERSION}")
|
|
message(STATUS "Packaging with tzdata version: ${TZDATA_VERSION}")
|
|
|
|
# each file in that dir (except of tab and localtime) store the info about timezone
|
|
execute_process(COMMAND
|
|
bash -c "cd ${TZDIR} && find * -type f -and ! -name '*.tab' -and ! -name 'localtime' | LC_ALL=C sort | paste -sd ';' -"
|
|
OUTPUT_STRIP_TRAILING_WHITESPACE
|
|
OUTPUT_VARIABLE TIMEZONES
|
|
COMMAND_ERROR_IS_FATAL ANY
|
|
)
|
|
|
|
file(APPEND ${TIMEZONES_FILE} "// autogenerated by ClickHouse/contrib/cctz-cmake/CMakeLists.txt\n")
|
|
file(APPEND ${TIMEZONES_FILE} "#include <incbin.h>\n")
|
|
|
|
set (COUNTER 1)
|
|
foreach(TIMEZONE ${TIMEZONES})
|
|
file(APPEND ${TIMEZONES_FILE} "INCBIN(resource_timezone${COUNTER}, \"${TZDIR}/${TIMEZONE}\");\n")
|
|
MATH(EXPR COUNTER "${COUNTER}+1")
|
|
endforeach(TIMEZONE)
|
|
|
|
file(APPEND ${TIMEZONES_FILE} "const char * auto_time_zones[] {\n" )
|
|
|
|
foreach(TIMEZONE ${TIMEZONES})
|
|
file(APPEND ${TIMEZONES_FILE} " \"${TIMEZONE}\",\n")
|
|
MATH(EXPR COUNTER "${COUNTER}+1")
|
|
endforeach(TIMEZONE)
|
|
|
|
file(APPEND ${TIMEZONES_FILE} " nullptr\n};\n\n")
|
|
|
|
file(APPEND ${TIMEZONES_FILE} "#include <string_view>\n\n")
|
|
file(APPEND ${TIMEZONES_FILE} "std::string_view getTimeZone(const char * name)\n{\n" )
|
|
|
|
set (COUNTER 1)
|
|
foreach(TIMEZONE ${TIMEZONES})
|
|
file(APPEND ${TIMEZONES_FILE} " if (std::string_view(\"${TIMEZONE}\") == name) return { reinterpret_cast<const char *>(gresource_timezone${COUNTER}Data), gresource_timezone${COUNTER}Size };\n")
|
|
MATH(EXPR COUNTER "${COUNTER}+1")
|
|
endforeach(TIMEZONE)
|
|
|
|
file(APPEND ${TIMEZONES_FILE} " return {};\n")
|
|
file(APPEND ${TIMEZONES_FILE} "}\n")
|
|
|
|
add_library (tzdata ${TIMEZONES_FILE})
|
|
target_link_libraries(tzdata ch_contrib::incbin)
|
|
target_link_libraries(_cctz tzdata)
|
|
|
|
add_library(ch_contrib::cctz ALIAS _cctz)
|